On Apache
Under GNU General Public License
2012-05-24 19:25 @38.107.179.236 Crawled by CCBot/1.0 (+http://www.commoncrawl.org/bot.html)
Moose(3pm) User Contributed Perl Documentation Moose(3pm)
NAME
Moose - A postmodern object system for Perl 5
SYNOPSIS
package Point;
use Moose; # automatically turns on strict and warnings
has 'x' => (is => 'rw', isa => 'Int');
has 'y' => (is => 'rw', isa => 'Int');
sub clear {
my $self = shift;
$self->x(0);
$self->y(0);
}
package Point3D;
use Moose;
extends 'Point';
has 'z' => (is => 'rw', isa => 'Int');
after 'clear' => sub {
my $self = shift;
$self->z(0);
};
DESCRIPTION
Moose is an extension of the Perl 5 object system.
The main goal of Moose is to make Perl 5 Object Oriented programming easier, more
consistent and less tedious. With Moose you can to think more about what you want to do
and less about the mechanics of OOP.
Additionally, Moose is built on top of Class::MOP, which is a metaclass system for Perl 5.
This means that Moose not only makes building normal Perl 5 objects better, but it
provides the power of metaclass programming as well.
New to Moose?
If you're new to Moose, the best place to start is the Moose::Manual docs, followed by the
Moose::Cookbook. The intro will show you what Moose is, and how it makes Perl 5 OO better.
The cookbook recipes on Moose basics will get you up to speed with many of Moose's
features quickly. Once you have an idea of what Moose can do, you can use the API
documentation to get more detail on features which interest you.
Moose Extensions
The "MooseX::" namespace is the official place to find Moose extensions. These extensions
can be found on the CPAN. The easiest way to find them is to search for them
(<http://search.cpan.org/search?query=MooseX::>), or to examine Task::Moose which aims to
keep an up-to-date, easily installable list of Moose extensions.
TRANSLATIONS
Much of the Moose documentation has been translated into other languages.
<http://github.com/jpa/Moose-Doc-JA>
BUILDING CLASSES WITH MOOSE
Moose makes every attempt to provide as much convenience as possible during class
construction/definition, but still stay out of your way if you want it to. Here are a few
items to note when building classes with Moose.
Unless specified with "extends", any class which uses Moose will inherit from
Moose::Object.
Moose will also manage all attributes (including inherited ones) that are defined with
"has". And (assuming you call "new", which is inherited from Moose::Object) this includes
properly initializing all instance slots, setting defaults where appropriate, and
performing any type constraint checking or coercion.
PROVIDED METHODS
Moose provides a number of methods to all your classes, mostly through the inheritance of
Moose::Object. There is however, one exception.
meta
This is a method which provides access to the current class's metaclass.
EXPORTED FUNCTIONS
Moose will export a number of functions into the class's namespace which may then be used
to set up the class. These functions all work directly on the current class.
extends (@superclasses)
This function will set the superclass(es) for the current class.
This approach is recommended instead of "use base", because "use base" actually
"push"es onto the class's @ISA, whereas "extends" will replace it. This is important
to ensure that classes which do not have superclasses still properly inherit from
Moose::Object.
with (@roles)
This will apply a given set of @roles to the local class.
has $name|@$names => %options
This will install an attribute of a given $name into the current class. If the first
parameter is an array reference, it will create an attribute for every $name in the
list. The %options are the same as those provided by Class::MOP::Attribute, in
addition to the list below which are provided by Moose (Moose::Meta::Attribute to be
more specific):
is => 'rw'|'ro'
The is option accepts either rw (for read/write) or ro (for read only). These will
create either a read/write accessor or a read-only accessor respectively, using
the same name as the $name of the attribute.
If you need more control over how your accessors are named, you can use the
reader, writer and accessor options inherited from Class::MOP::Attribute, however
if you use those, you won't need the is option.
isa => $type_name
The isa option uses Moose's type constraint facilities to set up runtime type
checking for this attribute. Moose will perform the checks during class
construction, and within any accessors. The $type_name argument must be a string.
The string may be either a class name or a type defined using Moose's type
definition features. (Refer to Moose::Util::TypeConstraints for information on how
to define a new type, and how to retrieve type meta-data).
coerce => (1|0)
This will attempt to use coercion with the supplied type constraint to change the
value passed into any accessors or constructors. You must have supplied a type
constraint in order for this to work. See Moose::Cookbook::Basics::Recipe5 for an
example.
does => $role_name
This will accept the name of a role which the value stored in this attribute is
expected to have consumed.
required => (1|0)
This marks the attribute as being required. This means a value must be supplied
during class construction, or the attribute must be lazy and have either a default
or a builder. Note that c<required> does not say anything about the attribute's
value, which can be "undef".
weak_ref => (1|0)
This will tell the class to store the value of this attribute as a weakened
reference. If an attribute is a weakened reference, it cannot also be coerced.
lazy => (1|0)
This will tell the class to not create this slot until absolutely necessary. If
an attribute is marked as lazy it must have a default supplied.
auto_deref => (1|0)
This tells the accessor whether to automatically dereference the value returned.
This is only legal if your "isa" option is either "ArrayRef" or "HashRef".
trigger => $code
The trigger option is a CODE reference which will be called after the value of the
attribute is set. The CODE ref will be passed the instance itself and the updated
value. If the attribute already had a value, this will be passed as the third
value to the trigger.
You can have a trigger on a read-only attribute.
NOTE: Triggers will only fire when you assign to the attribute, either in the
constructor, or using the writer. Default and built values will not cause the
trigger to be fired.
handles => ARRAY | HASH | REGEXP | ROLE | DUCKTYPE | CODE
The handles option provides Moose classes with automated delegation features.
This is a pretty complex and powerful option. It accepts many different option
formats, each with its own benefits and drawbacks.
NOTE: The class being delegated to does not need to be a Moose based class, which
is why this feature is especially useful when wrapping non-Moose classes.
All handles option formats share the following traits:
You cannot override a locally defined method with a delegated method; an exception
will be thrown if you try. That is to say, if you define "foo" in your class, you
cannot override it with a delegated "foo". This is almost never something you
would want to do, and if it is, you should do it by hand and not use Moose.
You cannot override any of the methods found in Moose::Object, or the "BUILD" and
"DEMOLISH" methods. These will not throw an exception, but will silently move on
to the next method in the list. My reasoning for this is that you would almost
never want to do this, since it usually breaks your class. As with overriding
locally defined methods, if you do want to do this, you should do it manually, not
with Moose.
You do not need to have a reader (or accessor) for the attribute in order to
delegate to it. Moose will create a means of accessing the value for you, however
this will be several times less efficient then if you had given the attribute a
reader (or accessor) to use.
Below is the documentation for each option format:
"ARRAY"
This is the most common usage for handles. You basically pass a list of method
names to be delegated, and Moose will install a delegation method for each
one.
"HASH"
This is the second most common usage for handles. Instead of a list of method
names, you pass a HASH ref where each key is the method name you want
installed locally, and its value is the name of the original method in the
class being delegated to.
This can be very useful for recursive classes like trees. Here is a quick
example (soon to be expanded into a Moose::Cookbook recipe):
package Tree;
use Moose;
has 'node' => (is => 'rw', isa => 'Any');
has 'children' => (
is => 'ro',
isa => 'ArrayRef',
default => sub { [] }
);
has 'parent' => (
is => 'rw',
isa => 'Tree',
weak_ref => 1,
handles => {
parent_node => 'node',
siblings => 'children',
}
);
In this example, the Tree package gets "parent_node" and "siblings" methods,
which delegate to the "node" and "children" methods (respectively) of the Tree
instance stored in the "parent" slot.
You may also use an array reference to curry arguments to the original method.
has 'thing' => (
...
handles => { set_foo => [ set => 'foo' ] },
);
# $self->set_foo(...) calls $self->thing->set('foo', ...)
The first element of the array reference is the original method name, and the
rest is a list of curried arguments.
"REGEXP"
The regexp option works very similar to the ARRAY option, except that it
builds the list of methods for you. It starts by collecting all possible
methods of the class being delegated to, then filters that list using the
regexp supplied here.
NOTE: An isa option is required when using the regexp option format. This is
so that we can determine (at compile time) the method list from the class.
Without an isa this is just not possible.
"ROLE"
With the role option, you specify the name of a role whose "interface" then
becomes the list of methods to handle. The "interface" can be defined as; the
methods of the role and any required methods of the role. It should be noted
that this does not include any method modifiers or generated attribute methods
(which is consistent with role composition).
"DUCKTYPE"
With the duck type option, you pass a duck type object whose "interface" then
becomes the list of methods to handle. The "interface" can be defined as; the
list of methods passed to "duck_type" to create a duck type object. For more
information on "duck_type" please check Moose::Util::TypeConstraints.
"CODE"
This is the option to use when you really want to do something funky. You
should only use it if you really know what you are doing, as it involves
manual metaclass twiddling.
This takes a code reference, which should expect two arguments. The first is
the attribute meta-object this handles is attached to. The second is the
metaclass of the class being delegated to. It expects you to return a hash
(not a HASH ref) of the methods you want mapped.
metaclass => $metaclass_name
This tells the class to use a custom attribute metaclass for this particular
attribute. Custom attribute metaclasses are useful for extending the capabilities
of the has keyword: they are the simplest way to extend the MOP, but they are
still a fairly advanced topic and too much to cover here, see
Moose::Cookbook::Meta::Recipe1 for more information.
See "Metaclass and Trait Name Resolution" for details on how a metaclass name is
resolved to a class name.
traits => [ @role_names ]
This tells Moose to take the list of @role_names and apply them to the attribute
meta-object. This is very similar to the metaclass option, but allows you to use
more than one extension at a time.
See "Metaclass and Trait Name Resolution" for details on how a trait name is
resolved to a role name.
Also see Moose::Cookbook::Meta::Recipe3 for a metaclass trait example.
builder => Str
The value of this key is the name of the method that will be called to obtain the
value used to initialize the attribute. See the builder option docs in
Class::MOP::Attribute
and/or Moose::Cookbook::Basics::Recipe8 for more information.
default => SCALAR | CODE
The value of this key is the default value which will initialize the attribute.
NOTE: If the value is a simple scalar (string or number), then it can be just
passed as is. However, if you wish to initialize it with a HASH or ARRAY ref,
then you need to wrap that inside a CODE reference. See the default option docs
in Class::MOP::Attribute for more information.
clearer => Str
Creates a method allowing you to clear the value, see the clearer option docs in
Class::MOP::Attribute for more information.
predicate => Str
Creates a method to perform a basic test to see if a value has been set in the
attribute, see the predicate option docs in Class::MOP::Attribute for more
information.
lazy_build => (0|1)
Automatically define lazy => 1 as well as builder => "_build_$attr", clearer =>
"clear_$attr', predicate => 'has_$attr' unless they are already defined.
initializer => Str
This may be a method name (referring to a method on the class with this attribute)
or a CODE ref. The initializer is used to set the attribute value on an instance
when the attribute is set during instance initialization (but not when the value
is being assigned to). See the initializer option docs in Class::MOP::Attribute
for more information.
documentation => $string
An arbitrary string that can be retrieved later by calling "$attr->documentation".
has +$name => %options
This is variation on the normal attribute creator "has" which allows you to clone and
extend an attribute from a superclass or from a role. Here is an example of the
superclass usage:
package Foo;
use Moose;
has 'message' => (
is => 'rw',
isa => 'Str',
default => 'Hello, I am a Foo'
);
package My::Foo;
use Moose;
extends 'Foo';
has '+message' => (default => 'Hello I am My::Foo');
What is happening here is that My::Foo is cloning the "message" attribute from its
parent class Foo, retaining the "is => 'rw'" and "isa => 'Str'" characteristics, but
changing the value in "default".
Here is another example, but within the context of a role:
package Foo::Role;
use Moose::Role;
has 'message' => (
is => 'rw',
isa => 'Str',
default => 'Hello, I am a Foo'
);
package My::Foo;
use Moose;
with 'Foo::Role';
has '+message' => (default => 'Hello I am My::Foo');
In this case, we are basically taking the attribute which the role supplied and
altering it within the bounds of this feature.
Note that you can only extend an attribute from either a superclass or a role, you
cannot extend an attribute in a role that composes over an attribute from another
role.
Aside from where the attributes come from (one from superclass, the other from a
role), this feature works exactly the same. This feature is restricted somewhat, so as
to try and force at least some sanity into it. You are only allowed to change the
following attributes:
default
Change the default value of an attribute.
coerce
Change whether the attribute attempts to coerce a value passed to it.
required
Change if the attribute is required to have a value.
documentation
Change the documentation string associated with the attribute.
lazy
Change if the attribute lazily initializes the slot.
isa You are allowed to change the type without restriction.
It is recommended that you use this freedom with caution. We used to only allow
for extension only if the type was a subtype of the parent's type, but we felt
that was too restrictive and is better left as a policy decision.
handles
You are allowed to add a new "handles" definition, but you are not allowed to
change one.
builder
You are allowed to add a new "builder" definition, but you are not allowed to
change one.
metaclass
You are allowed to add a new "metaclass" definition, but you are not allowed to
change one.
traits
You are allowed to add additional traits to the "traits" definition. These traits
will be composed into the attribute, but preexisting traits are not overridden, or
removed.
before $name|@names => sub { ... }
after $name|@names => sub { ... }
around $name|@names => sub { ... }
These three items are syntactic sugar for the before, after, and around method
modifier features that Class::MOP provides. More information on these may be found in
Moose::Manual::MethodModifiers and the Class::MOP::Class documentation.
super
The keyword "super" is a no-op when called outside of an "override" method. In the
context of an "override" method, it will call the next most appropriate superclass
method with the same arguments as the original method.
override ($name, &sub)
An "override" method is a way of explicitly saying "I am overriding this method from
my superclass". You can call "super" within this method, and it will work as expected.
The same thing can be accomplished with a normal method call and the "SUPER::" pseudo-
package; it is really your choice.
inner
The keyword "inner", much like "super", is a no-op outside of the context of an
"augment" method. You can think of "inner" as being the inverse of "super"; the
details of how "inner" and "augment" work is best described in the
Moose::Cookbook::Basics::Recipe6.
augment ($name, &sub)
An "augment" method, is a way of explicitly saying "I am augmenting this method from
my superclass". Once again, the details of how "inner" and "augment" work is best
described in the Moose::Cookbook::Basics::Recipe6.
confess
This is the "Carp::confess" function, and exported here because I use it all the time.
blessed
This is the "Scalar::Util::blessed" function, it is exported here because I use it all
the time. It is highly recommended that this is used instead of "ref" anywhere you
need to test for an object's class name.
METACLASS
When you use Moose, you can specify which metaclass to use:
use Moose -metaclass => 'My::Meta::Class';
You can also specify traits which will be applied to your metaclass:
use Moose -traits => 'My::Trait';
This is very similar to the attribute traits feature. When you do this, your class's
"meta" object will have the specified traits applied to it. See "Metaclass and Trait Name
Resolution" for more details.
Metaclass and Trait Name Resolution
By default, when given a trait name, Moose simply tries to load a class of the same name.
If such a class does not exist, it then looks for for a class matching
Moose::Meta::$type::Custom::Trait::$trait_name. The $type variable here will be one of
Attribute or Class, depending on what the trait is being applied to.
If a class with this long name exists, Moose checks to see if it has the method
"register_implementation". This method is expected to return the real class name of the
trait. If there is no "register_implementation" method, it will fall back to using
Moose::Meta::$type::Custom::Trait::$trait as the trait name.
The lookup method for metaclasses is the same, except that it looks for a class matching
Moose::Meta::$type::Custom::$metaclass_name.
If all this is confusing, take a look at Moose::Cookbook::Meta::Recipe3, which
demonstrates how to create an attribute trait.
UNIMPORTING FUNCTIONS
unimport
Moose offers a way to remove the keywords it exports, through the "unimport" method. You
simply have to say "no Moose" at the bottom of your code for this to work. Here is an
example:
package Person;
use Moose;
has 'first_name' => (is => 'rw', isa => 'Str');
has 'last_name' => (is => 'rw', isa => 'Str');
sub full_name {
my $self = shift;
$self->first_name . ' ' . $self->last_name
}
no Moose; # keywords are removed from the Person package
EXTENDING AND EMBEDDING MOOSE
To learn more about extending Moose, we recommend checking out the "Extending" recipes in
the Moose::Cookbook, starting with Moose::Cookbook::Extending::Recipe1, which provides an
overview of all the different ways you might extend Moose.
Moose->init_meta(for_class => $class, base_class => $baseclass, metaclass => $metaclass)
The "init_meta" method sets up the metaclass object for the class specified by
"for_class". This method injects a a "meta" accessor into the class so you can get at this
object. It also sets the class's superclass to "base_class", with Moose::Object as the
default.
"init_meta" returns the metaclass object for $class.
You can specify an alternate metaclass with the "metaclass" option.
For more detail on this topic, see Moose::Cookbook::Extending::Recipe2.
This method used to be documented as a function which accepted positional parameters. This
calling style will still work for backwards compatibility, but is deprecated.
import
Moose's "import" method supports the Sub::Exporter form of "{into => $pkg}" and
"{into_level => 1}".
NOTE: Doing this is more or less deprecated. Use Moose::Exporter instead, which lets you
stack multiple "Moose.pm"-alike modules sanely. It handles getting the exported functions
into the right place for you.
throw_error
An alias for "confess", used by internally by Moose.
METACLASS COMPATIBILITY AND MOOSE
Metaclass compatibility is a thorny subject. You should start by reading the "About
Metaclass compatibility" section in the "Class::MOP" docs.
Moose will attempt to resolve a few cases of metaclass incompatibility when you set the
superclasses for a class, unlike "Class::MOP", which simply dies if the metaclasses are
incompatible.
In actuality, Moose fixes incompatibility for all of a class's metaclasses, not just the
class metaclass. That includes the instance metaclass, attribute metaclass, as well as its
constructor class and destructor class. However, for simplicity this discussion will just
refer to "metaclass", meaning the class metaclass, most of the time.
Moose has two algorithms for fixing metaclass incompatibility.
The first algorithm is very simple. If all the metaclass for the parent is a subclass of
the child's metaclass, then we simply replace the child's metaclass with the parent's.
The second algorithm is more complicated. It tries to determine if the metaclasses only
"differ by roles". This means that the parent and child's metaclass share a common
ancestor in their respective hierarchies, and that the subclasses under the common
ancestor are only different because of role applications. This case is actually fairly
common when you mix and match various "MooseX::*" modules, many of which apply roles to
the metaclass.
If the parent and child do differ by roles, Moose replaces the metaclass in the child with
a newly created metaclass. This metaclass is a subclass of the parent's metaclass, does
all of the roles that the child's metaclass did before being replaced. Effectively, this
means the new metaclass does all of the roles done by both the parent's and child's
original metaclasses.
Ultimately, this is all transparent to you except in the case of an unresolvable conflict.
The MooseX:: namespace
Generally if you're writing an extension for Moose itself you'll want to put your
extension in the "MooseX::" namespace. This namespace is specifically for extensions that
make Moose better or different in some fundamental way. It is traditionally not for a
package that just happens to use Moose. This namespace follows from the examples of the
"LWPx::" and "DBIx::" namespaces that perform the same function for "LWP" and "DBI"
respectively.
CAVEATS
o It should be noted that "super" and "inner" cannot be used in the same method.
However, they may be combined within the same class hierarchy; see
t/014_override_augment_inner_super.t for an example.
The reason for this is that "super" is only valid within a method with the "override"
modifier, and "inner" will never be valid within an "override" method. In fact,
"augment" will skip over any "override" methods when searching for its appropriate
"inner".
This might seem like a restriction, but I am of the opinion that keeping these two
features separate (yet interoperable) actually makes them easy to use, since their
behavior is then easier to predict. Time will tell whether I am right or not (UPDATE:
so far so good).
GETTING HELP
We offer both a mailing list and a very active IRC channel.
The mailing list is moose AT perl.org. You must be subscribed to send a message. To
subscribe, send an empty message to moose-subscribe AT perl.org
You can also visit us at <#moose on irc.perl.org>. This channel is quite active, and
questions at all levels (on Moose-related topics ;) are welcome.
ACKNOWLEDGEMENTS
I blame Sam Vilain for introducing me to the insanity that is meta-models.
I blame Audrey Tang for then encouraging my meta-model habit in #perl6.
Without Yuval "nothingmuch" Kogman this module would not be possible, and it certainly
wouldn't have this name ;P
The basis of the TypeContraints module was Rob Kinyon's idea originally, I just ran with
it.
Thanks to mst & chansen and the whole #moose posse for all the early
ideas/feature-requests/encouragement/bug-finding.
Thanks to David "Theory" Wheeler for meta-discussions and spelling fixes.
SEE ALSO
<http://www.iinteractive.com/moose>
This is the official web home of Moose, it contains links to our public SVN repository
as well as links to a number of talks and articles on Moose and Moose related
technologies.
The Moose is flying, a tutorial by Randal Schwartz
Part 1 - <http://www.stonehenge.com/merlyn/LinuxMag/col94.html>
Part 2 - <http://www.stonehenge.com/merlyn/LinuxMag/col95.html>
Several Moose extension modules in the "MooseX::" namespace.
See <http://search.cpan.org/search?query=MooseX::> for extensions.
Moose stats on ohloh.net - <http://www.ohloh.net/projects/moose>
Books
The Art of the MetaObject Protocol
I mention this in the Class::MOP docs too, this book was critical in the development
of both modules and is highly recommended.
Papers
<http://www.cs.utah.edu/plt/publications/oopsla04-gff.pdf>
This paper (suggested by lbr on #moose) was what lead to the implementation of the
"super"/"override" and "inner"/"augment" features. If you really want to understand
them, I suggest you read this.
BUGS
All complex software has bugs lurking in it, and this module is no exception.
Please report any bugs to "bug-moose AT rt.org", or through the web interface at
<http://rt.cpan.org>.
FEATURE REQUESTS
We are very strict about what features we add to the Moose core, especially the user-
visible features. Instead we have made sure that the underlying meta-system of Moose is as
extensible as possible so that you can add your own features easily.
That said, occasionally there is a feature needed in the meta-system to support your
planned extension, in which case you should either email the mailing list (moose AT perl.org)
or join us on IRC at <irc://irc.perl.org/#moose> to discuss. The
Moose::Manual::Contributing has more detail about how and when you can contribute.
AUTHOR
Moose is an open project, there are at this point dozens of people who have contributed,
and can contribute. If you have added anything to the Moose project you have a commit bit
on this file and can add your name to the list.
CABAL
However there are only a few people with the rights to release a new version of Moose. The
Moose Cabal are the people to go to with questions regarding the wider purview of Moose,
and help out maintaining not just the code but the community as well.
Stevan (stevan) Little <stevan AT iinteractive.com>
Yuval (nothingmuch) Kogman
Shawn (sartak) Moore <sartak AT bestpractical.com>
Dave (autarch) Rolsky <autarch AT urth.org>
Jesse (doy) Luehrs <doy at tozt dot net>
Hans Dieter (confound) Pearcey <hdp AT pobox.com>
Chris (perigrin) Prather
Florian Ragwitz <rafl AT debian.org>
OTHER CONTRIBUTORS
Aankhen
Adam (Alias) Kennedy
Anders (Debolaz) Nor Berle
Nathan (kolibrie) Gray
Christian (chansen) Hansen
Eric (ewilhelm) Wilhelm
Guillermo (groditi) Roditi
Jess (castaway) Robinson
Matt (mst) Trout
Robert (phaylon) Sedlacek
Robert (rlb3) Boone
Scott (konobi) McWhirter
Shlomi (rindolf) Fish
Wallace (wreis) Reis
Jonathan (jrockway) Rockway
Piotr (dexter) Roszatycki
Sam (mugwump) Vilain
Cory (gphat) Watson
Dylan Hardison (doc fixes)
... and many other #moose folks
COPYRIGHT AND LICENSE
Copyright 2006-2009 by Infinity Interactive, Inc.
<http://www.iinteractive.com>
This library is free software; you can redistribute it and/or modify it under the same
terms as Perl itself.
perl v5.10.0 2009-11-18 Moose(3pm)
Generated by $Id: phpMan.php,v 4.49 2006/02/26 13:18:18 chedong Exp $ Author: Che Dong
On Apache
Under GNU General Public License
2012-05-24 19:25 @38.107.179.236 Crawled by CCBot/1.0 (+http://www.commoncrawl.org/bot.html)